postwgts.F90

Go to the documentation of this file.

module postwgts

  use esmf

  use gengrid_kinds, only : cl,cm,cs
  use grdvars,       only : nv, mastertask
  use charstrings,   only : dirout, res, staggerlocs, logmsg
  use netcdf

  implicit none

  contains
  
  subroutine make_postwgts

  ! local variables
  character(len=CL) :: fsrc, fdst, fwgt
  character(len= 2) :: cstagger

  character(len=CM), dimension(2) :: methodname = (/'conserve', 'bilinear'/)

  type(esmf_regridmethod_flag) :: method
  ! the number of possible destination grids depends on the source grid resolution
  integer :: k,rc,nd,ndest
  character(len=CS), allocatable, dimension(:) :: destgrds
 
!---------------------------------------------------------------------
! set the destination grids
!---------------------------------------------------------------------

  if(trim(res) .eq. '400')return

  if(trim(res) .eq. '100')then
   ndest = 1
   allocate(destgrds(ndest))
   destgrds = (/'1p0 '/)
  end if
  if(trim(res) .eq. '050')then
   ndest = 2
   allocate(destgrds(ndest))
   destgrds = (/'1p0 ', '0p5 '/)
  end if
  if(trim(res) .eq. '025')then
   ndest = 3
   allocate(destgrds(ndest))
   destgrds = (/'1p0 ', '0p5 ', '0p25'/)
  end if

!---------------------------------------------------------------------
! use ESMF to create the weights for unstaggering the points onto
! the Ct staggers for post; the destination is always Ct
!---------------------------------------------------------------------

  method=esmf_regridmethod_bilinear
  fdst = trim(dirout)//'/'//'Ct.mx'//trim(res)//'_SCRIP.nc'
  do k = 2,nv
   cstagger = trim(staggerlocs(k))
   fsrc = trim(dirout)//'/'//trim(cstagger)//'.mx'//trim(res)//'_SCRIP.nc'
   fwgt = trim(dirout)//'/'//'tripole.mx'//trim(res)//'.'//trim(cstagger)//'.to.Ct.bilinear.nc'
   if(mastertask) then
     logmsg = 'creating weight file '//trim(fwgt)
     print '(a)',trim(logmsg)
   end if

   call esmf_regridweightgen(srcfile=trim(fsrc),dstfile=trim(fdst), &
                        weightfile=trim(fwgt), regridmethod=method, &
                        ignoredegenerate=.true., &
                        unmappedaction=esmf_unmappedaction_ignore, rc=rc)
   if (esmf_logfounderror(rctocheck=rc, msg=esmf_logerr_passthru, &
     line=__line__, file=__file__)) call esmf_finalize(endflag=esmf_end_abort)
  end do

!---------------------------------------------------------------------
! use ESMF to create the weights from the Ct tripole to the rectilinear
! grids with conservative and bilinear methods for post; the source
! file is always Ct
!---------------------------------------------------------------------
 
  do nd = 1,ndest
   fsrc = trim(dirout)//'/'//'Ct.mx'//trim(res)//'_SCRIP.nc'
   fdst = trim(dirout)//'/rect.'//trim(destgrds(nd))//'_SCRIP.nc'
   
     do k = 1,size(methodname)
      if(trim(methodname(k)) .eq. 'bilinear')method=esmf_regridmethod_bilinear
      if(trim(methodname(k)) .eq. 'conserve')method=esmf_regridmethod_conserve

      fwgt = trim(dirout)//'/'//'tripole.mx'//trim(res)//'.Ct.to.rect.'//trim(destgrds(nd)) &
             //'.'//trim(methodname(k))//'.nc'
      if(mastertask) then
        logmsg = 'creating weight file '//trim(fwgt)
        print '(a)',trim(logmsg)
      end if
     
      call esmf_regridweightgen(srcfile=trim(fsrc),dstfile=trim(fdst), &
                           weightfile=trim(fwgt), regridmethod=method, &
                           ignoredegenerate=.true., &
                           unmappedaction=esmf_unmappedaction_ignore, rc=rc)
      if (esmf_logfounderror(rctocheck=rc, msg=esmf_logerr_passthru, &
        line=__line__, file=__file__)) call esmf_finalize(endflag=esmf_end_abort)
     end do
  end do

  deallocate(destgrds)

  end subroutine make_postwgts
end module postwgts