driver.F90

Go to the documentation of this file.

 program driver  

 use model_grid
 use source_grid
 use program_setup
 use utils
 use esmf

 implicit none

 integer                      :: rc
 integer                      :: localpet
 integer                      :: npets

 type(esmf_vm)                :: vm
 type(esmf_regridmethod_flag) :: method

!-------------------------------------------------------------------------
! Initialize MPI and ESMF environments.
!-------------------------------------------------------------------------

 call mpi_init(rc)

 print*,"- INITIALIZE ESMF"
 call esmf_initialize(rc=rc)
 if(esmf_logfounderror(rctocheck=rc,msg=esmf_logerr_passthru,line=__line__,file=__file__)) &
    call error_handler("INITIALIZING ESMF", rc)

 print*,"- CALL VMGetGlobal"
 call esmf_vmgetglobal(vm, rc=rc)
 if(esmf_logfounderror(rctocheck=rc,msg=esmf_logerr_passthru,line=__line__,file=__file__)) &
    call error_handler("IN VMGetGlobal.", rc)

 print*,"- CALL VMGet"
 call esmf_vmget(vm, localpet=localpet, petcount=npets, rc=rc)
 if(esmf_logfounderror(rctocheck=rc,msg=esmf_logerr_passthru,line=__line__,file=__file__)) &
    call error_handler("IN VMGet.", rc)

 print*,'- NPETS IS  ',npets
 print*,'- LOCAL PET ',localpet

!-------------------------------------------------------------------------
! Program set up step.
!-------------------------------------------------------------------------

 call read_setup_namelist(localpet)

!-------------------------------------------------------------------------
! Define fv3 model grid.
!-------------------------------------------------------------------------

 call define_model_grid(localpet, npets)

!-------------------------------------------------------------------------
! Interpolate fields.  Vegetation type must be done first as
! it defines which points are permanent land ice.
!-------------------------------------------------------------------------

 call define_source_grid(localpet, npets, input_vegetation_type_file)
 if (fract_vegsoil_type) then
   print*,'- WILL OUTPUT VEGETATION TYPE FRACTION AND DOMINANT CATEGORY.'
   call interp_frac_cats(localpet, input_vegetation_type_file)
 else
   print*,'- WILL OUTPUT DOMINANT VEGETATION TYPE.'
   method=esmf_regridmethod_nearest_stod
   call interp(localpet, method, input_vegetation_type_file)
 endif
 call source_grid_cleanup

! Snow free albedo

 if (trim(input_snowfree_albedo_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_snowfree_albedo_file)
   method=esmf_regridmethod_bilinear
   if (trim(snowfree_albedo_method)=="conserve") method=esmf_regridmethod_conserve
   call interp(localpet, method, input_snowfree_albedo_file)
   call source_grid_cleanup
 endif

! Maximum snow albedo

 if (trim(input_maximum_snow_albedo_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_maximum_snow_albedo_file)
   method=esmf_regridmethod_bilinear
   if (trim(maximum_snow_albedo_method)=="conserve") method=esmf_regridmethod_conserve
   call interp(localpet, method, input_maximum_snow_albedo_file)
   call source_grid_cleanup
 endif

! FACSF - fractional coverage for strong zenith angle
! dependant albedo.

 if (trim(input_facsf_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_facsf_file)
   method=esmf_regridmethod_bilinear
   call interp(localpet, method, input_facsf_file)
   call source_grid_cleanup
 endif

! Soil substrate temperature

 if (trim(input_substrate_temperature_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_substrate_temperature_file)
   method=esmf_regridmethod_bilinear
   call interp(localpet, method, input_substrate_temperature_file)
   call source_grid_cleanup
 endif

! Slope type

 if (trim(input_slope_type_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_slope_type_file)
   method=esmf_regridmethod_nearest_stod
   call interp(localpet, method, input_slope_type_file)
   call source_grid_cleanup
 endif

! Soil type

 if (trim(input_soil_type_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_soil_type_file)
   if (fract_vegsoil_type) then
     print*,'- WILL OUTPUT SOIL TYPE FRACTION AND DOMINANT CATEGORY.'
     call interp_frac_cats(localpet, input_soil_type_file)
   else
     print*,'- WILL OUTPUT DOMINANT SOIL TYPE.'
     method=esmf_regridmethod_nearest_stod
     call interp(localpet, method, input_soil_type_file)
   endif
   call source_grid_cleanup
 endif

! Soil color

 if (trim(input_soil_color_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_soil_color_file)
   method=esmf_regridmethod_nearest_stod
   call interp(localpet, method, input_soil_color_file)
   call source_grid_cleanup
 endif


! Vegetation greenness

 if (trim(input_vegetation_greenness_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_vegetation_greenness_file)
   method=esmf_regridmethod_bilinear
   if (trim(vegetation_greenness_method)=="conserve") method=esmf_regridmethod_conserve
   call interp(localpet, method, input_vegetation_greenness_file)
   call source_grid_cleanup
 endif

! Leaf Area Index

 if (trim(input_leaf_area_index_file) /= "NULL") then
   call define_source_grid(localpet, npets, input_leaf_area_index_file)
   method=esmf_regridmethod_bilinear
   if (trim(leaf_area_index_method)=="conserve") method=esmf_regridmethod_conserve
   call interp(localpet, method, input_leaf_area_index_file)
   call source_grid_cleanup
 endif

 call model_grid_cleanup

 print*,"- CALL ESMF_finalize"
 call esmf_finalize(endflag=esmf_end_keepmpi, rc=rc)

 call mpi_finalize(rc)

 print*,'- DONE.'
 stop

 end program driver