postwgts.F90

Go to the documentation of this file.

module postwgts

  use esmf

  use gengrid_kinds, only : cl,cm,cs
  use grdvars,       only : nv
  use charstrings,   only : dirout, res, logmsg
  use netcdf

  implicit none

contains

  subroutine make_postwgts

    ! local variables
    character(len=CL) :: fsrc, fdst, fwgt

    character(len=CM), dimension(2) :: methodname = (/'conserve', 'bilinear'/)

    type(ESMF_RouteHandle)       :: rh
    type(ESMF_RegridMethod_Flag) :: method
    ! the number of possible destination grids depends on the source grid resolution
    integer :: k,rc,nd,ndest
    character(len=CS), allocatable, dimension(:) :: destgrds

    !---------------------------------------------------------------------
    ! set the destination grids
    !---------------------------------------------------------------------

    if(trim(res) .eq. '500')then
       ndest = 1
       allocate(destgrds(ndest))
       destgrds = (/'5p00'/)
    end if
    if(trim(res) .eq. '100')then
       ndest = 2
       allocate(destgrds(ndest))
       destgrds = (/'5p00', '1p00'/)
    end if
    if(trim(res) .eq. '050')then
       ndest = 3
       allocate(destgrds(ndest))
       destgrds = (/'5p00', '1p00', '0p50'/)
    end if
    if(trim(res) .eq. '025')then
       ndest = 4
       allocate(destgrds(ndest))
       destgrds = (/'5p00', '1p00', '0p50', '0p25'/)
    end if

    !---------------------------------------------------------------------
    ! use ESMF to create the weights from the Ct tripole to the rectilinear
    ! grids with conservative and bilinear methods for post; the source
    ! file is always Ct
    !---------------------------------------------------------------------

    do nd = 1,ndest
       fsrc = trim(dirout)//'/'//'Ct.mx'//trim(res)//'_SCRIP.nc'
       fdst = trim(dirout)//'/rect.'//trim(destgrds(nd))//'_SCRIP.nc'

       do k = 1,size(methodname)
          if(trim(methodname(k)) .eq. 'bilinear')method=esmf_regridmethod_bilinear
          if(trim(methodname(k)) .eq. 'conserve')method=esmf_regridmethod_conserve

          fwgt = trim(dirout)//'/'//'tripole.mx'//trim(res)//'.Ct.to.rect.'//trim(destgrds(nd)) &
               //'.'//trim(methodname(k))//'.nc'
          logmsg = 'creating weight file '//trim(fwgt)
          print '(a)',trim(logmsg)

          call esmf_regridweightgen(srcfile=trim(fsrc),dstfile=trim(fdst), &
               weightfile=trim(fwgt), regridmethod=method,                 &
               ignoredegenerate=.true., regridroutehandle=rh,              &
               unmappedaction=esmf_unmappedaction_ignore, rc=rc)
          if (esmf_logfounderror(rctocheck=rc, msg=esmf_logerr_passthru, &
               line=__line__, file=__file__)) call esmf_finalize(endflag=esmf_end_abort)
       end do
    end do

    deallocate(destgrds)

  end subroutine make_postwgts
end module postwgts