utils.F90

Go to the documentation of this file.

 
 
 module utils
 
 implicit none
 
 public
 
 character(len=512) :: topo_file = "orog"
 character(len=128) :: topo_field = "orog_filt"
 character(len=128) :: mask_field = "slmsk"
 character(len=512) :: grid_file = "atmos_mosaic.nc"
 
 logical :: zero_ocean = .true.  
 logical :: nested = .false.     
 logical :: regional = .false.   
 
 integer :: grid_type = 0
 
 real    :: stretch_fac = 1.0
 real    :: res = 48.
 
 contains
 
 subroutine read_namelist
 
 implicit none
 
 integer :: stdunit = 6, unit=7, io_status
 logical :: opened
 
 namelist /filter_topo_nml/ topo_file, topo_field, mask_field, grid_file, zero_ocean, &
        stretch_fac, res, nested, grid_type, regional
 
 do
   inquire( unit=unit, opened=opened )
   if( .NOT.opened )exit
   unit = unit + 1
   if( unit.EQ.100 )call handle_err(-1, 'Unable to locate unit number.' )
 end do
 
 open( unit=unit, file='input.nml', iostat=io_status )
 read( unit,filter_topo_nml, iostat=io_status )
 close(unit)
 
 if (io_status > 0) call handle_err(-1, 'Error reading input.nml')
 
 write (stdunit, nml=filter_topo_nml)
 
 end subroutine read_namelist
 
  subroutine fill_regional_halo(data, halo)
    integer, intent(in)                               :: halo
    real, dimension(1-halo:,1-halo:,:), intent(inout) :: data
    integer :: h, i_st, i_ed, j_st, j_ed
 
    i_st=lbound(data,1)+halo
    i_ed=ubound(data,1)-halo
    j_st=lbound(data,2)+halo
    j_ed=ubound(data,2)-halo
 
    do h = 1, halo
      data(i_st:i_ed, j_st-1   , :) = 2* data(i_st:i_ed, j_st     , :) - data(i_st:i_ed, j_st+1   , :)! north
      data(i_st:i_ed, j_ed+1   , :) = 2* data(i_st:i_ed, j_ed     , :) - data(i_st:i_ed, j_ed-1   , :)! south
      data(i_st-1   , j_st:j_ed, :) = 2* data(i_st     , j_st:j_ed, :) - data(i_st+1   , j_st:j_ed, :)! east
      data(i_ed+1   , j_st:j_ed, :) = 2* data(i_ed     , j_st:j_ed, :) - data(i_ed-1   , j_st:j_ed, :)! west
 
      data(i_st-1, j_st-1, :) = (data(i_st-1, j_st, :) + data(i_st, j_st-1, :))*0.5  !NW Corner
      data(i_ed+1, j_st-1, :) = (data(i_ed+1, j_st, :) + data(i_ed, j_st-1, :))*0.5  !NE Corner
      data(i_st-1, j_ed+1, :) = (data(i_st-1, j_ed, :) + data(i_st, j_ed+1, :))*0.5  !SW Corner
      data(i_ed+1, j_ed+1, :) = (data(i_ed+1, j_ed, :) + data(i_ed, j_ed+1, :))*0.5  !SE Corner
 
      i_st=i_st-1
      i_ed=i_ed+1
      j_st=j_st-1
      j_ed=j_ed+1
    enddo
 
  end subroutine fill_regional_halo
 
 subroutine handle_err(status, string)
 
 implicit none
 
#include <netcdf.inc>
 
 integer,          intent(in) :: status
 character(len=*), intent(in) :: string
 character(len=256) :: errmsg
 
 if (status .ne. nf_noerr) then
   errmsg = nf_strerror(status)
   errmsg = trim(errmsg) // " " // trim(string)
   print *, "FATAL ERROR:"
   print *, trim(errmsg)
   error stop 'Stopped'
 endif
 
 end subroutine handle_err
 
 end module utils